Re: Bright Backgrounds ?!

 BBS: Inland Empire Archive
Date: 05-26-92 (09:10)             Number: 179
From: ROB SMETANA @ 914/201        Refer#: 178
  To: JOE CRIGGER                   Recvd: NO  
Subj: Re: Bright Backgrounds ?!      Conf: (2) Quik_Bas

'**** part 2  (Sub BrightBackground (TurnBrightBGOn))

Defint a-z

SUB BrightBackground (TurnBrightBGOn)  '...CGA or higher!

   SHARED Inregs AS RegType, Outregs AS RegType

   DEF SEG = &H40                '...Video BIOS data

   ' If you DON'T have Crescent's QuickPak Pro MONITOR,
   ' edit this to specify either EGA/VGA -or- CGA.
   ' You might pass a 2nd "monitor" variable; then the
   ' Select Case below would still be relevant.

   SELECT CASE Monitor

      CASE IS > 3                '...EGA or VGA

         IF TurnBrightBGOn THEN
              Inregs.bx = 0
         ELSE Inregs.bx = 1
         END IF

         Inregs.ax = &H1003
         CALL Interrupt(&H10, Inregs, Outregs)

      CASE 3                     '...CGA

         RegStat = PEEK(&H65)
         IF TurnBrightBGOn THEN
            RegStat = RegStat AND &HDF
         ELSE
            RegStat = RegStat OR &H20
         END IF

         '...Get the video port to use
         VidReg = 4 + PEEK(&H63) + PEEK(&H64) * 256
         OUT VidReg, RegStat

   END SELECT

   DEF SEG


END SUB


--- RBBSMail 17.3A
 # Origin: PCUG BBS - San Francisco HST/V.32 415-621-2609 (RBBS 8:914/201.0)
 * Origin: Gateway System to/from RBBS-NET (RBBS-PC 1:10/8)