Graphics formats

 BBS: Inland Empire Archive
Date: 03-25-92 (22:38)             Number: 148
From: STEVE HALKO                  Refer#: NONE
  To: CORIDON HENSHAW               Recvd: NO  
Subj: Graphics formats               Conf: (2) Quik_Bas

CH>VPIC /R works just as well.  BUT if I want to save a screen from mode
CH>8-12, I need to do bank switching, where do I POKE to swithch
CH>the vid mem banks?

  No POKEs - gotta use OUTs:

  'Save a graphics screen
  DEFINT A - Z
  DEF SEG = &HA000            'Video segment
  FOR i = 0 TO NrBitPlanes - 1
      OUT &H3CE, 4            'Select the Read Map Select Register
      OUT &H3CF, i            'Select the bit plane to save
      BSAVE "PLANE" + CHR$(i + 48), 0, NrBytes
  NEXT i

  The variables NrBitPlanes and NrBytes have the following values:

  Screen     NrBitPlanes    NrBytes
  ------     -----------    -------
    7            4           8000
    8            4          16000
    9            4          28000
   10            2          28000
   11            4          38400
   12            4          38400

  You'll end up with 4 files (2 for SCREEN 10):

      Filename       Contents
      --------       --------
       PLANE0        Blue bit plane
       PLANE1        Green bit plane
       PLANE2        Red bit plane
       PLANE3        Intensity bit plane


  Restoring these screens is a little different:

  'Restore a graphics screen
  DEFINT A - Z
  DEF SEG = &HA000
  FOR i = 0 TO NrBitPlanes - 1
      OUT &H3C4, 2               'Select the Map Mask Register
      OUT &H3C5, 2 ^ i           'Select the bit plane to restore
      BLOAD "PLANE" + CHR$(i + 48), 0
  NEXT i

 * SLMR 2.1a * A seminar on Time Travel will be held two weeks ago.

--- DB B1062/002487
 * Origin: Gulf Coast BBS -QuickSHARE #2- (904)563-2547 HST/V.32bis (1:365/12)