Re: Fossil Info

 BBS: Inland Empire Archive
Date: 03-19-92 (18:58)             Number: 172
From: BOB PERKINS                  Refer#: NONE
  To: JOHN JANES                    Recvd: NO  
Subj: Re: Fossil Info                Conf: (2) Quik_Bas

 JJ>   Ok, I am stumped.  What's wrong with this sub.??  When I
 JJ>  run it, the system is locked.  I'm sure it has something
 JJ>  to do with how I am setting the .es(seg) and .di(offset)
 JJ>  but just can't get them right.  So please if anyone knows
 JJ>  what's wrong, PLEASE HELP..!!

  I came up with this and it seems to work okay..  I'm not
sure why yours didn't work.  I'm reading the data into a
structure to make it easier to decipher later.

 =======================================================================

  '$INCLUDE: 'qb.bi'
  DIM regs AS regtypex
  TYPE temp
   structsize AS INTEGER
   spec AS STRING * 1
   revision AS STRING * 1
   pointer AS LONG
   inbuffsize AS INTEGER
   inbytesleft AS INTEGER
   outbuffsize AS INTEGER
   outbytesleft AS INTEGER
   scrnwidth AS STRING * 1
   scrnlength AS STRING * 1
   actualbaud AS STRING * 1
  END TYPE
  DIM fossinfo AS temp
  CLS
  regs.ax = &H1B00
  regs.dx = 1
  regs.cx = 19
  regs.es = VARSEG(fossinfo)
  regs.di = VARPTR(fossinfo)
  interruptX &H14, regs, regs
  PRINT "Stucture size           = "; fossinfo.structsize
  PRINT "Fossil Spec             = "; ASC(fossinfo.spec)
  PRINT "Revision Level          = "; ASC(fossinfo.revision)
  PRINT "ASCII ID Pointer        = "; fossinfo.pointer
  PRINT "Size of input buffer    = "; fossinfo.inbuffsize
  PRINT "Bytes in input buffer   = "; fossinfo.inbytesleft
  PRINT "Size of output buffer   = "; fossinfo.outbuffsize
  PRINT "Bytes in output buffer  = "; fossinfo.outbytesleft
  PRINT "Width of Screen         = "; ASC(fossinfo.scrnwidth)
  PRINT "Length of Screen        = "; ASC(fossinfo.scrnlength)
  PRINT "Actual Baud Rate Byte   = "; ASC(fossinfo.actualbaud)
  END



--- Msg V4.5
 * Origin: Reciprocity Failure  (1:124/4115.236)