Banner

 BBS: Inland Empire Archive
Date: 10-16-92 (01:08)             Number: 389
From: MARK BUTLER                  Refer#: NONE
  To: BOBBY MORGAN                  Recvd: NO  
Subj: Banner                         Conf: (2) Quik_Bas

On (12 Oct 92) Bobby Morgan wrote to Mark Butler...

 BM> MARK,
 BM> No net is safe for you to hide ..he he (evil laugh) You told me i
 BM> could yell at ya anytime...so here goes... The code you posted was
 BM> great...I do need one more thing.....
 BM> I would like to be able to put in other data statements.. and have
 BM> them come on  the screen as ..I love QuickBASIC.. goes off.. heres a
 BM> repost  (if ur old like me u forgot) (34 BTW)

 I'm a just few years older but I think my forgetfulness is more due
 to the lifstyle I lived in the 60's than mere age accounts for <grin>

 Anyway, try this one on for size. I think it's what you are trying to
 do....
==========================8< Cut Here 8<=============================
DEFINT A-Z
DECLARE SUB pause (ticks)
DIM Banner$(1 TO 4)

    CLS
    LOCATE , , 0

'*** define our stuff to display...
    Bars$ = SPACE$(5) + STRING$(70, 219) + SPACE$(5)
'*** we're now gonna have more than one banner
    Banner$(1) = SPACE$(30) + "-* I " + CHR$(3) + " QuickBASIC *-"
    Banner$(1) = Banner$(1) + SPACE$(30)
    Banner$(2) = SPACE$(30) + "-* I LIKE VB-DOS *-" + SPACE$(30)
    Banner$(3) = SPACE$(24) + "-* I'm not sure about VB-WIN *-"
    Banner$(3) = Banner$(3) + SPACE$(24)
    Banner$(4) = SPACE$(28) + "-* I want PowerBASIC *-" + SPACE$(28)

'*** if we want them to display one after the other we'll just
'*** add `em all together and display `em 80 chars at a time.
    AllBanners$ = Banner$(1) + Banner$(2) + Banner$(3) + Banner$(4)

    COLOR 0, 3
    LOCATE 25, 30
    PRINT "  Press ESC to end  ";
    COLOR 7, 0

    DO UNTIL INKEY$ = CHR$(27)  '*** exit if ESC key is pressed
        Bars$ = MID$(Bars$, 2, 79) + LEFT$(Bars$, 1)
'*** we'll do the same thing with our big conglomerate banner that we
'*** did with our other one. Take a char off the beginning and add it on
'*** to the end repeatedly....
        AllBanners$ = MID$(AllBanners$, 2, LEN(AllBanners$))
        AllBanners$ = AllBanners$ + LEFT$(AllBanners$, 1)
        LOCATE 2, 1
        PRINT Bars$;   '*** print the top Bar
        LOCATE 12, 1
'*** -=BUT=- we'll, only print the first 80 chars of the big string
'*** at any given time.
        PRINT LEFT$(AllBanners$, 80); '*** print the Banner
        LOCATE 24, 1
        PRINT Bars$;   '*** print the bottom Bar
        pause 2        '*** small delay before we do it again
    LOOP
    CLS
    END

SUB pause (ticks)
    DEF SEG = 0
    DO UNTIL TestTick > ticks
        LastTick = GetTick
        GetTick = PEEK(&H46C)
        IF LastTick <> GetTick THEN
            TestTick = TestTick + 1
        END IF
    LOOP
    DEF SEG
END SUB
==========================8< Cut Here 8<=============================

 And that's it.


 תש [-M-H-B-] שת


--- PPoint 1.35
 * Origin: Terminal Oasis, Portland OR (1:105/330.5)