Re: Bload/bsave 320x200x

 BBS: Inland Empire Archive
Date: 10-24-93 (10:55)             Number: 296
From: STEVE DEMO                   Refer#: NONE
  To: PAT SARNOWSKI                 Recvd: NO  
Subj: Re: Bload/bsave 320x200x       Conf: (2) Quik_Bas

 -=> Quoting Pat Sarnowski to All <=-

 PS> Does anyone out there know how to BLOAD/BSAVE a picture
 PS> currently on the screen in mode 13 (320x200x256)? I can't

 Yep I can,

DEFINT A-Z
DECLARE SUB SaveScreen (File$)
DECLARE SUB LoadScreen (File$)
RANDOMIZE TIMER
SCREEN 13
j = 16
FOR x = 1 TO 200
 j = j + 1: IF j > 30 THEN j = 16
 LINE (1, x)-(320, x), j
NEXT
FOR Loops = 1 TO 100
    Y = INT(RND * 190) + 1
    x = INT(RND * 310) + 1
    Size = INT(RND * 20) + 1
    Clur = INT(RND * 150) + 31
    CIRCLE (x, Y), Size, Clur
    PAINT (x, Y), Clur, Clur
NEXT
  REDIM Array(32004)
  GET (0, 0)-(319, 199), Array
  PUT (0, 0), Array, PSET
  CLS : SLEEP 1
  PUT (0, 0), Array, PSET
  SLEEP 1
  PRINT "Now From Disk": SLEEP 1
  PUT (0, 0), Array, PSET
  SaveScreen "Temp.BSV"
  CLS : SLEEP 1
  LoadScreen "Temp.bsv"
  SOUND 400, 1: SOUND 600, 1: SOUND 300, 1
  KILL "temp.bsv"

SUB LoadScreen (File$)
'$DYNAMIC
IF File$ = "" THEN EXIT SUB
REDIM Array1a(32004)
DEF SEG = VARSEG(Array1a(0))
 BLOAD File$, VARPTR(Array1a(0))
DEF SEG
PUT (0, 0), Array1a, PSET
ERASE Array1a
END SUB

REM $STATIC
SUB SaveScreen (File$)
'$DYNAMIC
IF File$ = "" THEN EXIT SUB
REDIM Array1a(32004)
GET (0, 0)-(319, 199), Array1a
DEF SEG = VARSEG(Array1a(0))
 BSAVE File$, VARPTR(Array1a(0)), 64000
DEF SEG
ERASE Array1a
END SUB


Hows that ?

Steve Demo
$$40
... I had a cat once....tasted like chicken.
___ Blue Wave/QWK v2.11

--- Maximus 2.01wb
 * Origin: Semper Fi BBS  Ft. Wayne, IN  (219) 424-4292 (1:236/21)